func check[report: Array] : bool
    let increasing: bool = array.nth(report, 0) < array.nth(report, 1)

    for i in 0..report->size-1
        if array.nth(report, i) > array.nth(report, i + 1) && increasing
            return false
        if array.nth(report, i) < array.nth(report, i + 1) && !increasing
            return false

        let diff: i64 = math.abs(array.nth(report, i) - array.nth(report, i + 1))
        if diff < 1 || diff > 3
            return false

    return true

func part1[data: Array] : void
    let out = 0

    for i in 0..data->size
        if check(array.nth(data, i))
            out = out + 1

    io.println_i64(out)

func part2[data: Array] : void
    let out = 0

    for i in 0..data->size
        if check(array.nth(data, i))
            out = out + 1
        else
            let arr: Array = array.nth(data, i)
            for j in 0..arr->size
                let sliced: Array = array.concat(array.slice(arr, 0, j), array.slice(arr, j + 1, arr->size - (j + 1)))
                
                if check(sliced)
                    out = out + 1
                    break

    io.println_i64(out)

func main[] : i64
    let lines: Array = io.read_file("input.txt") |> str.split("\n")

    let data: Array = []
    for i in 0..lines->size
        let line: str = array.nth(lines, i)

        let report: Array = str.split(line, " ")
        for i in 0..report->size
            array.set(report, i, str.parse_i64(array.nth(report, i)))
        array.push(data, report)

    part1(data)
    part2(data)