func part1_is_invalid_id[s: str] : bool
    len := str.len(s)
    if len % 2 != 0
        return false

    first := str.substr(s, 0, len / 2)
    second := str.substr(s, len / 2, len / 2)

    return str.equal(first, second)

func part1[ranges: Array] : void
    sum := 0

    for i in 0..ranges->size
        parts := array.nth(ranges, i) |> str.split("-")
        start := array.nth(parts, 0) |> str.parse_i64()
        end := array.nth(parts, 1) |> str.parse_i64()

        for n in (start)..end+1
            if part1_is_invalid_id(str.from_i64(n))
                sum += n
    
    io.println_i64(sum)

// had to cheat this one
func part2_is_invalid_id[s: str] : bool
    len := str.len(s)
    if len < 2
        return false
    for div in 1..(len / 2 + 1)
        if len % div == 0
            u := str.substr(s, 0, div)
            is_repeat := true
            for k in 1..(len / div)
                segment := str.substr(s, k * div, div)
                if !str.equal(segment, u)
                    is_repeat = false
            if is_repeat
                return true
    return false

func part2[ranges: Array] : void
    sum := 0

    for i in 0..ranges->size
        parts := array.nth(ranges, i) |> str.split("-")
        start := array.nth(parts, 0) |> str.parse_i64()
        end := array.nth(parts, 1) |> str.parse_i64()

        for n in (start)..end+1
            if part2_is_invalid_id(str.from_i64(n))
                sum += n
    
    io.println_i64(sum)

func main[] : i64
    ~input, ok := io.read_text_file("input.txt")
    if !ok
        panic("failed to open input.txt")
    
    ranges := str.split(input, ",")

    part1(ranges)
    part2(ranges)